Gecko [ www.foryou-vip.com ]

Name	Size	Permission	Date
bundle	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
core	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
dev	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
doc	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
exe	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
launcher	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
lib	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
path	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
pip	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
tcltk	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
test	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
tools	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
ucrt	[ DIR ]	drwxr-xr-x	2024-03-19 22:46
README.txt	22.36 KB	-rw-r--r--	2024-03-19 22:46
build.bat	2.66 KB	-rw-r--r--	2024-03-19 22:46
buildrelease.bat	9.67 KB	-rw-r--r--	2024-03-19 22:46
common.wxs	4.83 KB	-rw-r--r--	2024-03-19 22:46
common_en-US.wxl_template	1.45 KB	-rw-r--r--	2024-03-19 22:46
csv_to_wxs.py	4.95 KB	-rw-r--r--	2024-03-19 22:46
generate_md5.py	679 B	-rw-r--r--	2024-03-19 22:46
get_externals.bat	2.67 KB	-rw-r--r--	2024-03-19 22:46
make_appx.ps1	2.19 KB	-rw-r--r--	2024-03-19 22:46
make_cat.ps1	1.39 KB	-rw-r--r--	2024-03-19 22:46
make_zip.proj	1.86 KB	-rw-r--r--	2024-03-19 22:46
msi.props	9.07 KB	-rw-r--r--	2024-03-19 22:46
msi.targets	5.74 KB	-rw-r--r--	2024-03-19 22:46
purge.py	1.93 KB	-rw-r--r--	2024-03-19 22:46
sdktools.psm1	1.54 KB	-rw-r--r--	2024-03-19 22:46
sign_build.ps1	1 KB	-rw-r--r--	2024-03-19 22:46
testrelease.bat	4.07 KB	-rw-r--r--	2024-03-19 22:46
uploadrelease.bat	5.01 KB	-rw-r--r--	2024-03-19 22:46
uploadrelease.proj	6.71 KB	-rw-r--r--	2024-03-19 22:46
uploadrelease.ps1	5.28 KB	-rw-r--r--	2024-03-19 22:46
wix.props	966 B	-rw-r--r--	2024-03-19 22:46

Rename

@echo off
setlocal
set D=%~dp0
set PCBUILD=%D%..\..\PCbuild\

set BUILDX86=
set BUILDX64=
set BUILDDOC=
set BUILDTEST=
set BUILDPACK=
set REBUILD=

:CheckOpts
if    "%~1" EQU "-h" goto Help
if /I "%~1" EQU "-x86" (set BUILDX86=1) && shift && goto CheckOpts
if /I "%~1" EQU "-Win32" (set BUILDX86=1) && shift && goto CheckOpts
if /I "%~1" EQU "-x64" (set BUILDX64=1) && shift && goto CheckOpts
if    "%~1" EQU "--doc" (set BUILDDOC=1) && shift && goto CheckOpts
if    "%~1" EQU "--no-test-marker" (set BUILDTEST=) && shift && goto CheckOpts
if    "%~1" EQU "--test-marker" (set BUILDTEST=--test-marker) && shift && goto CheckOpts
if    "%~1" EQU "--pack" (set BUILDPACK=1) && shift && goto CheckOpts
if    "%~1" EQU "-r" (set REBUILD=-r) && shift && goto CheckOpts

if not defined BUILDX86 if not defined BUILDX64 (set BUILDX86=1) && (set BUILDX64=1)

call "%D%get_externals.bat"
call "%PCBUILD%find_msbuild.bat" %MSBUILD%
if ERRORLEVEL 1 (echo Cannot locate MSBuild.exe on PATH or as MSBUILD variable & exit /b 2)

if defined BUILDX86 call "%PCBUILD%build.bat" -p Win32 -d -e %REBUILD% %BUILDTEST%
if errorlevel 1 exit /B %ERRORLEVEL%
if defined BUILDX86 call "%PCBUILD%build.bat" -p Win32 -e %REBUILD% %BUILDTEST%
if errorlevel 1 exit /B %ERRORLEVEL%

if defined BUILDX64 call "%PCBUILD%build.bat" -p x64 -d -e %REBUILD% %BUILDTEST%
if errorlevel 1 exit /B %ERRORLEVEL%
if defined BUILDX64 call "%PCBUILD%build.bat" -p x64 -e %REBUILD% %BUILDTEST%
if errorlevel 1 exit /B %ERRORLEVEL%

if defined BUILDDOC call "%PCBUILD%..\Doc\make.bat" html
if errorlevel 1 exit /B %ERRORLEVEL%

rem Build the launcher MSI separately
%MSBUILD% "%D%launcher\launcher.wixproj" /p:Platform=x86
if errorlevel 1 exit /B %ERRORLEVEL%

set BUILD_CMD="%D%bundle\snapshot.wixproj"
if defined BUILDTEST (
    set BUILD_CMD=%BUILD_CMD% /p:UseTestMarker=true
)
if defined BUILDPACK (
    set BUILD_CMD=%BUILD_CMD% /p:Pack=true
)
if defined REBUILD (
    set BUILD_CMD=%BUILD_CMD% /t:Rebuild
)

if defined BUILDX86 %MSBUILD% /p:Platform=x86 %BUILD_CMD%
if errorlevel 1 exit /B %ERRORLEVEL%

if defined BUILDX64 %MSBUILD% /p:Platform=x64 %BUILD_CMD%
if errorlevel 1 exit /B %ERRORLEVEL%

exit /B 0

:Help
echo build.bat [-x86] [-x64] [--doc] [-h] [--test-marker] [--pack] [-r]
echo.
echo    -x86                Build x86 installers
echo    -x64                Build x64 installers
echo    --doc               Build CHM documentation
echo    --test-marker       Build with test markers
echo    --no-test-marker    Build without test markers (default)
echo    --pack              Embed core MSIs into installer
echo    -r                  Rebuild rather than incremental build