Gecko [ www.foryou-vip.com ]

Name	Size	Permission	Date
file	[ DIR ]	drwxr-xr-x	2020-08-24 23:47
urn	[ DIR ]	drwxr-xr-x	2020-08-24 23:47
Escape.pm	6.86 KB	-rw-r--r--	2016-01-08 04:15
Heuristic.pm	6.37 KB	-rw-r--r--	2016-01-08 04:15
IRI.pm	820 B	-rw-r--r--	2016-01-08 04:15
QueryParam.pm	4.77 KB	-rw-r--r--	2016-01-08 04:15
Split.pm	2.32 KB	-rw-r--r--	2016-01-08 04:15
URL.pm	5.36 KB	-rw-r--r--	2016-01-08 04:15
WithBase.pm	3.77 KB	-rw-r--r--	2016-01-08 04:15
_foreign.pm	133 B	-rw-r--r--	2016-01-08 04:15
_generic.pm	5.71 KB	-rw-r--r--	2016-01-08 04:15
_idna.pm	2.05 KB	-rw-r--r--	2016-01-08 04:15
_ldap.pm	3.2 KB	-rw-r--r--	2016-01-08 04:15
_login.pm	257 B	-rw-r--r--	2016-01-08 04:15
_punycode.pm	4.54 KB	-rw-r--r--	2016-01-08 04:15
_query.pm	2.5 KB	-rw-r--r--	2016-01-08 04:15
_segment.pm	442 B	-rw-r--r--	2016-01-08 04:15
_server.pm	3.66 KB	-rw-r--r--	2016-01-08 04:15
_userpass.pm	1.04 KB	-rw-r--r--	2016-01-08 04:15
data.pm	3.34 KB	-rw-r--r--	2016-01-08 04:15
file.pm	9.53 KB	-rw-r--r--	2016-01-08 04:15
ftp.pm	1.06 KB	-rw-r--r--	2016-01-08 04:15
gopher.pm	2.4 KB	-rw-r--r--	2016-01-08 04:15
http.pm	451 B	-rw-r--r--	2016-01-08 04:15
https.pm	170 B	-rw-r--r--	2016-01-08 04:15
ldap.pm	2.88 KB	-rw-r--r--	2016-01-08 04:15
ldapi.pm	467 B	-rw-r--r--	2016-01-08 04:15
ldaps.pm	170 B	-rw-r--r--	2016-01-08 04:15
mailto.pm	1.27 KB	-rw-r--r--	2016-01-08 04:15
mms.pm	151 B	-rw-r--r--	2016-01-08 04:15
news.pm	1.45 KB	-rw-r--r--	2016-01-08 04:15
nntp.pm	153 B	-rw-r--r--	2016-01-08 04:15
pop.pm	1.2 KB	-rw-r--r--	2016-01-08 04:15
rlogin.pm	155 B	-rw-r--r--	2016-01-08 04:15
rsync.pm	233 B	-rw-r--r--	2016-01-08 04:15
rtsp.pm	151 B	-rw-r--r--	2016-01-08 04:15
rtspu.pm	152 B	-rw-r--r--	2016-01-08 04:15
sftp.pm	124 B	-rw-r--r--	2016-01-08 04:15
sip.pm	1.69 KB	-rw-r--r--	2016-01-08 04:15
sips.pm	169 B	-rw-r--r--	2016-01-08 04:15
snews.pm	198 B	-rw-r--r--	2016-01-08 04:15
ssh.pm	201 B	-rw-r--r--	2016-01-08 04:15
telnet.pm	154 B	-rw-r--r--	2016-01-08 04:15
tn3270.pm	154 B	-rw-r--r--	2016-01-08 04:15
urn.pm	2.15 KB	-rw-r--r--	2016-01-08 04:15

Rename

package URI::_punycode;

use strict;
use warnings;

our $VERSION = '1.71';
$VERSION = eval $VERSION;

use Exporter 'import';
our @EXPORT = qw(encode_punycode decode_punycode);

use integer;

our $DEBUG = 0;

use constant BASE => 36;
use constant TMIN => 1;
use constant TMAX => 26;
use constant SKEW => 38;
use constant DAMP => 700;
use constant INITIAL_BIAS => 72;
use constant INITIAL_N => 128;

my $Delimiter = chr 0x2D;
my $BasicRE   = qr/[\x00-\x7f]/;

sub _croak { require Carp; Carp::croak(@_); }

sub digit_value {
    my $code = shift;
    return ord($code) - ord("A") if $code =~ /[A-Z]/;
    return ord($code) - ord("a") if $code =~ /[a-z]/;
    return ord($code) - ord("0") + 26 if $code =~ /[0-9]/;
    return;
}

sub code_point {
    my $digit = shift;
    return $digit + ord('a') if 0 <= $digit && $digit <= 25;
    return $digit + ord('0') - 26 if 26 <= $digit && $digit <= 36;
    die 'NOT COME HERE';
}

sub adapt {
    my($delta, $numpoints, $firsttime) = @_;
    $delta = $firsttime ? $delta / DAMP : $delta / 2;
    $delta += $delta / $numpoints;
    my $k = 0;
    while ($delta > ((BASE - TMIN) * TMAX) / 2) {
	$delta /= BASE - TMIN;
	$k += BASE;
    }
    return $k + (((BASE - TMIN + 1) * $delta) / ($delta + SKEW));
}

sub decode_punycode {
    my $code = shift;

my $n      = INITIAL_N;
    my $i      = 0;
    my $bias   = INITIAL_BIAS;
    my @output;

if ($code =~ s/(.*)$Delimiter//o) {
	push @output, map ord, split //, $1;
	return _croak('non-basic code point') unless $1 =~ /^$BasicRE*$/o;
    }

while ($code) {
	my $oldi = $i;
	my $w    = 1;
    LOOP:
	for (my $k = BASE; 1; $k += BASE) {
	    my $cp = substr($code, 0, 1, '');
	    my $digit = digit_value($cp);
	    defined $digit or return _croak("invalid punycode input");
	    $i += $digit * $w;
	    my $t = ($k <= $bias) ? TMIN
		: ($k >= $bias + TMAX) ? TMAX : $k - $bias;
	    last LOOP if $digit < $t;
	    $w *= (BASE - $t);
	}
	$bias = adapt($i - $oldi, @output + 1, $oldi == 0);
	warn "bias becomes $bias" if $DEBUG;
	$n += $i / (@output + 1);
	$i = $i % (@output + 1);
	splice(@output, $i, 0, $n);
	warn join " ", map sprintf('%04x', $_), @output if $DEBUG;
	$i++;
    }
    return join '', map chr, @output;
}

sub encode_punycode {
    my $input = shift;
    my @input = split //, $input;

my $n     = INITIAL_N;
    my $delta = 0;
    my $bias  = INITIAL_BIAS;

my @output;
    my @basic = grep /$BasicRE/, @input;
    my $h = my $b = @basic;
    push @output, @basic;
    push @output, $Delimiter if $b && $h < @input;
    warn "basic codepoints: (@output)" if $DEBUG;

while ($h < @input) {
	my $m = min(grep { $_ >= $n } map ord, @input);
	warn sprintf "next code point to insert is %04x", $m if $DEBUG;
	$delta += ($m - $n) * ($h + 1);
	$n = $m;
	for my $i (@input) {
	    my $c = ord($i);
	    $delta++ if $c < $n;
	    if ($c == $n) {
		my $q = $delta;
	    LOOP:
		for (my $k = BASE; 1; $k += BASE) {
		    my $t = ($k <= $bias) ? TMIN :
			($k >= $bias + TMAX) ? TMAX : $k - $bias;
		    last LOOP if $q < $t;
		    my $cp = code_point($t + (($q - $t) % (BASE - $t)));
		    push @output, chr($cp);
		    $q = ($q - $t) / (BASE - $t);
		}
		push @output, chr(code_point($q));
		$bias = adapt($delta, $h + 1, $h == $b);
		warn "bias becomes $bias" if $DEBUG;
		$delta = 0;
		$h++;
	    }
	}
	$delta++;
	$n++;
    }
    return join '', @output;
}

sub min {
    my $min = shift;
    for (@_) { $min = $_ if $_ <= $min }
    return $min;
}

1;
__END__

=head1 NAME

URI::_punycode - encodes Unicode string in Punycode

=head1 SYNOPSIS

use URI::_punycode;
  $punycode = encode_punycode($unicode);
  $unicode  = decode_punycode($punycode);

=head1 DESCRIPTION

URI::_punycode is a module to encode / decode Unicode strings into
Punycode, an efficient encoding of Unicode for use with IDNA.

This module requires Perl 5.6.0 or over to handle UTF8 flagged Unicode
strings.

=head1 FUNCTIONS

This module exports following functions by default.

=over 4

=item encode_punycode

$punycode = encode_punycode($unicode);

takes Unicode string (UTF8-flagged variable) and returns Punycode
encoding for it.

=item decode_punycode

$unicode = decode_punycode($punycode)

takes Punycode encoding and returns original Unicode string.

=back

These functions throw exceptions on failure. You can catch 'em via
C<eval>.

=head1 AUTHOR

Tatsuhiko Miyagawa E<lt>miyagawa@bulknews.netE<gt> is the author of
IDNA::Punycode v0.02 which was the basis for this module.

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=head1 SEE ALSO

L<IDNA::Punycode>, RFC 3492

=cut